DigiCert Terraform Provider のサンプル設定

DigiCert Terraform Provider プラグインを使用すると、DigiCert ONE プラットフォームから証明書を管理できます。このプラグインは、Terraform と DigiCert ONE API の間でブリッジとして機能し、シームレスな証明書管理を保証します。

開始する前に

Terraform プランの実行時にこのプラグインを使用するには、API キーとホスト URL を使用してプラグインを設定する必要があります。
REST API 用の証明書プロファイルが作成されていることを確認してください。
注記
ユーザーバインディングの手順では、サービスユーザーを使用することを推奨します。ユーザーを選択しない場合は、この証明書プロファイルに対する認証に任意の API キーを使用できます。
digicert_certificate コアリソースを使用して、common_name、dns_names、csr などの証明書パラメータを定義します。

これらのパラメータを設定すると、プラグインは安全な通信の確保、証明書のプロビジョニング、証明書の追跡を確実に実行するようになります。DigiCert Terraform Provider の統合に関する詳細と、各種の証明書管理コマンドについては、『HashiCorp Terraform Registry』を参照してください。

設定

Terraform Provider の設定、秘密鍵の生成、証明書出力の定義には main.tf ファイルを作成する必要があります。設定する変数を宣言するには variables.tf ファイルを使用します。

例 1. 設定（main.tf）

terraform {
  required_providers {
    digicert = {
      source  = "digicert/digicert"
      version = "~> 0.1"
    }
    tls = {
      source  = "hashicorp/tls"
      version = "~> 4.0"
    }
    local = {
      source  = "hashicorp/local"
      version = "~> 2.0"
    }
  }
}

# Configure DigiCert provider
provider "digicert" {
  api_key = var.digicert_api_key
  url     = var.digicert_url
}

# Generate private key
resource "tls_private_key" "server_key" {
  algorithm = var.private_key_algorithm
  rsa_bits  = var.private_key_rsa_bits
}

# Generate CSR
resource "tls_cert_request" "server_csr" {
  private_key_pem = tls_private_key.server_key.private_key_pem

  subject {
    common_name  = var.common_name
    organization = var.organization
    country      = var.country
  }

  dns_names = var.dns_names
}

# Request certificate from DigiCert
resource "digicert_certificate" "server_cert" {
  profile_id  = var.digicert_profile_id
  common_name = var.common_name
  csr         = tls_cert_request.server_csr.cert_request_pem
}

# Save files locally
resource "local_file" "private_key" {
  content         = tls_private_key.server_key.private_key_pem
  filename        = var.private_key_filename
  file_permission = var.private_key_file_permission
}

resource "local_file" "certificate" {
  content         = digicert_certificate.server_cert.certificate
  filename        = var.certificate_filename
  file_permission = var.certificate_file_permission
}

# Outputs
output "certificate_serial_number" {
  value = digicert_certificate.server_cert.serial_number
}

output "files_created" {
  value = {
    private_key = var.private_key_filename
    certificate = var.certificate_filename
  }
}

例 2. 変数（variables.tf）

variable "digicert_api_key" {
  description = "DigiCert API key for authentication"
  type        = string
  sensitive   = true
}

variable "digicert_url" {
  description = "DigiCert API URL"
  type        = string
}

variable "digicert_profile_id" {
  description = "DigiCert profile ID for certificate requests"
  type        = string
}

variable "common_name" {
  description = "Common name for the certificate"
  type        = string
}

variable "organization" {
  description = "Organization name for the certificate"
  type        = string
}

variable "country" {
  description = "Country code for the certificate"
  type        = string
}

variable "dns_names" {
  description = "List of DNS names for the certificate"
  type        = list(string)
}

variable "private_key_algorithm" {
  description = "Algorithm for private key generation"
  type        = string
}

variable "private_key_rsa_bits" {
  description = "Number of bits for RSA private key"
  type        = number
}

variable "private_key_filename" {
  description = "Filename for the private key file"
  type        = string
}

variable "certificate_filename" {
  description = "Filename for the certificate file"
  type        = string
}

variable "private_key_file_permission" {
  description = "File permissions for the private key file"
  type        = string
}

variable "certificate_file_permission" {
  description = "File permissions for the certificate file"
  type        = string
}

サンプルの設定スニペット

サンプルのスニペット（`terraform.tfvars`）

terraform.tfvars ファイルには、variables.tf ファイルで宣言された変数の実際の値が含まれます。

# DigiCert Configuration
digicert_api_key = "01gdthbbejkejlk2944kjfkjdvvcbcbmcmm2"
digicert_url     = "https://one.digicert.com"
digicert_profile_id = "fjhrh-djfh-sjshjhs"

# Certificate Details
common_name  = "name.io"
organization = "Your Organization"
country      = "Name of country"
dns_names    = [
  "sample.io",
  "www.sample.io"
]

# Private Key Configuration
private_key_algorithm = "RSA"
private_key_rsa_bits  = 2048

# Output Files
private_key_filename = "sample.io.key"
certificate_filename = "sample.io.crt"
private_key_file_permission = "0600"
certificate_file_permission = "0644"

このセクションの内容:

DigiCert Terraform Provider のサンプル設定

開始する前に

注記

設定

サンプルの設定スニペット

サンプルのスニペット（terraform.tfvars）

サンプルのスニペット（`terraform.tfvars`）